CELLNETS Excel開発の専門会社

【VBA入門】OneDriveでThisWorkbook.Pathがhttpsになる原因と、ローカルパスに変換する対策

OneDrive上のフォルダを指定すると、取得したPATHがhttpsで始まるURLに変わってしまう

PCのマイドキュメント内に格納してある「フォルダ」を選択したのに、取得PATHがなんかへん

SharePointとかHttpとか、これじゃ前に進めない・・・・。

みなさん、こんにちは。セルネッツ竹本です。
今回は、「フォルダの取得PATHが、Http・・・」記述に変わってしまう事象をテーマに、解説をしたいと思います。

結論から言うと、ThisWorkbook.PathがURLになるのは、ブックがOneDriveで同期されているためです。
VBAの関数でローカルのパスに変換するか、そのフォルダの同期(バックアップ)を外すことで解決できます。

この記事では、次のことがわかります。

  • ThisWorkbook.Pathがhttpsで始まるURLになる原因
  • OneDrive上でもローカルのパスを取得するVBAの関数(ソース公開)
  • この方法で変換できないケースと注意点
OneDrive環境のマクロ対応

OneDriveに移したら、マクロがエラーで止まるようになった?

  • フォルダ選択でhttpから始まるパスが返り、処理が止まる
  • 昨日まで動いていたマクロが、PCの入れ替え後に動かなくなった
  • 共有フォルダとOneDriveの混在で、保存先がバラバラになる

そのお悩み、クラウド環境に合わせたマクロの改修で解決できます。Excel専門のシステム開発会社『セルネッツ』なら、OneDrive上でもローカルのパスを扱えるよう処理を見直せます。新しいPCやクラウド環境での動作確認もお任せください。前任者が作ったマクロの引き継ぎにも対応します。

\Excel専門特化 × 低価格 × スピード対応/

OneDrive環境でのマクロ不具合を相談する

全国対応・お見積もり無料

ThisWorkbook.Pathがhttpsで始まるURLになる原因

OneDriveで同期しているフォルダのブックでは、ThisWorkbook.Pathがローカルのパスではなく、クラウド上の保存先のURLを返します。
見た目はPCの中のフォルダでも、VBAにはWeb上の場所として伝わるのが原因です。

◆いったい何が起きているのか。この間は問題なかったのに・・・。

「OneDrive」は、オンラインストレージとして、Microsoft社が提供してくれる「クラウドサービス」です。

しかし、何も考えず、ただ無料だからという理由で、インストールSetUpしてしまうと、デスクトップやドキュメントなどのフォルダがWeb上のクラウド領域にアップロードされてしまうので、注意が必要です。

実は、どのフォルダをクラウド領域にアップロードしたいかは、ちゃんと尋ねてきているのです。

対象になるのは、デスクトップ・ドキュメント・画像などの標準のフォルダです。
(参考:Microsoft サポート「OneDrive でフォルダーをバックアップする」)

これによる影響として、VBAからは、ローカル環境ではなく、WEBクラウド環境の格納PATHが返されます。
こうなってしまうと、フォルダは確かにローカルに見えていても、VBAは処理できず実行時エラーが発生してしまいます。

実際には、マイドキュメントにあるように見えても、クラウド上の領域と連動が成功している場合は、通常の「PATH取得Module」では正しく取得できないため、驚かれる方も多いのでは。
たとえば、こんなふうに・・・。

'★★★★★★★★★★★★★★★★★★★★★★★★★
' [実際のPATH]
' C:\Users\cn101\cellnets\00.Share2308
'   ↓こうなってしまう
' https://・・・・ドキュメント/なんちゃら
'★★★★★★★★★★★★★★★★★★★★★★★★★

返ってくるURLの形は、法人向けと個人向けのOneDriveで異なります。

種類ThisWorkbook.Pathが返すURLの例ローカルのフォルダ(環境変数)
法人向け(OneDrive for Business)https://会社名-my.sharepoint.com/personal/ユーザー名_ドメイン/Documents/フォルダOneDriveCommercial
個人向けhttps://d.docs.live.net/英数字のID/フォルダOneDriveConsumer

このURLのままDir関数やファイルを開く処理に渡すと、パスが見つからずにエラーになります。

OneDrive上でもローカルのPATHを取得する方法

URLの「/Documents」やIDより後ろの部分を取り出し、PCのOneDriveフォルダのパスにつなげ直します。

◆OneDrive上にあってもローカル環境PATHを取得するにはどうするか

これを回避するには、一時的に、「OneDrive」同期を終了、停止する方法もありますが、VBAプログラム側で、その判定を行ったうえで、ローカルのPATH取得をするには、以下で対応できます。

↓(A)Call する側の記述

'関数をCallして、結果をもらいます!
P_実BP = OneDrive_Url_Path変換(ThisWorkbook.Path)

↓(B)Callされる側のModule

'※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※
Public Function OneDrive_Url_Path変換(S_Url As String) As String
'*** Ver 3.4 OneDrive上で起動した場合、Thisworkbook.PathがURLとなる件の対応(2020/07/16)
'※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※
Const Cns_OneDrive法人パターン As String = "*my.sharepoint.com*"
'法人向けOneDriveのURLか否かを判定するためのLike右辺値

Static S_path区切り As String
Static S_OneDrive法人Path As String
Static S_OneDrive個人Path As String

Dim S_パス位置 As Long

'引数がURLでない場合、引数はローカルパスと判断してそのまま返す。
If Not (S_Url Like "https://*") Then

    OneDrive_Url_Path変換 = S_Url
    Exit Function

End If

If (S_path区切り = "") Then
    S_path区切り = Application.PathSeparator

    '法人向けOneDrive(OneDrive for Business)のパス
    S_OneDrive法人Path = Environ("OneDriveCommercial")
    If (S_OneDrive法人Path = "") Then
        S_OneDrive法人Path = Environ("OneDrive")
    End If

    '個人向けOneDriveのパス
    S_OneDrive個人Path = Environ("OneDriveConsumer")
    If (S_OneDrive個人Path = "") Then
        S_OneDrive個人Path = Environ("OneDrive")
    End If

End If

'法人向けOneDrive:S_Url="https://会社名-my.sharepoint.com/personal/ユーザー名_domain_com/Documentsファイルパス")
If (S_Url Like Cns_OneDrive法人パターン) Then

    S_パス位置 = InStr(1, S_Url, "/Documents") + 10                         '10 = Len("/Documents")
    OneDrive_Url_Path変換 = S_OneDrive法人Path & Replace(Mid(S_Url, S_パス位置), "/", S_path区切り)

'個人向けOneDrive:S_Url="https://d.docs.live.net/CID番号/ファイルパス"
Else

    '********************************************************************************
    '         1         2         3         4         5         6         7         8
    '12345678901234567890123456789012345678901234567890123456789012345678901234567890
    'https://d.docs.live.net/f53c0b88b096e170/デスクトップ/Excel_Ichiran_Ver3.4
    '********************************************************************************

    S_パス位置 = InStr(9, S_Url, "/")                                       '9 = Len("https://") + 1
    S_パス位置 = InStr(S_パス位置 + 1, S_Url, "/")
    OneDrive_Url_Path変換 = S_OneDrive個人Path & Replace(Mid(S_Url, S_パス位置), "/", S_path区切り)

End If

End Function

戻り値は、変数名「P_実BP」に格納されます。(意味は、Public型の実行BookPathを略しただけです・・・)
法人契約と個人とで分かれるところも、なんだか面倒です。

法人向けの判定に使う「*my.sharepoint.com*」の前後の「*」は、Like演算子のワイルドカードです。
「*」を省くと判定が常に一致しなくなり、法人向けのURLを個人向けとして変換してしまうので注意してください。

変換したパスは、フォルダ選択ダイアログの初期フォルダにもそのまま使えます。
指定の方法は、フォルダ選択ダイアログの初期フォルダを指定する方法で解説しています。

この方法で変換できないケースと注意点

この関数は、自分のOneDriveを同期している場合を前提にしています。
次のような場合は、正しいローカルのパスにならないことがあります。

  • ほかの人から共有されたフォルダ:「マイファイルにショートカットを追加」したフォルダは、URLとPCのフォルダ構成が一致しません。
  • SharePointやTeamsのライブラリを同期したフォルダ:URLが「/sites/〜」になり、/Documentsの位置で切り分けられません。
  • 同期していない(Webだけにある)ブック:PCにフォルダが無いため、変換してもそのパスは存在しません。

変換したあとは、Dir関数などでフォルダが本当にあるかを確かめてから処理に進むと安全です。
フォルダの有無を確かめて操作する例は、指定したフォルダを削除する方法で紹介しています。

業務用のツールなら、OneDriveの同期対象から外したフォルダや、社内の共有フォルダに置く運用にするのも確実な方法です。
バックアップを止める手順は、上で紹介したMicrosoft サポートのページに記載されています。
クラウドでExcelを共有するときの注意点は、Excelを共有するときの注意点(Dropbox)もご覧ください。

よくある質問

昨日まで動いていたのに、急にURLが返るようになったのはなぜですか?

PCの入れ替えやOneDriveの初期設定で、デスクトップやドキュメントのバックアップが有効になった可能性があります。
ブックの保存場所が、OneDriveの同期フォルダの中に変わっていないか確認してください。

ActiveWorkbook.PathやFullNameも同じようにURLになりますか?

なります。
OneDriveで同期しているブックでは、Path・FullNameのどちらもURLを返すことがあるため、同じ関数で変換してから使います。

フォルダ選択ダイアログで選んだパスもURLになりますか?

ダイアログでPCのフォルダを選んだ場合は、通常はローカルのパスが返ります。
URLになりやすいのは、ThisWorkbook.Pathのようにブック自身の場所を取得するときです。
フォルダ選択の基本は、ExcelVBA定番処理「フォルダ選択」で紹介しています。

まとめ|URLはローカルのパスに変換してから使う

今回のテーマは、「クラウド上でもローカルのPATHを取得する方法」について、解説を行いました。

OneDriveで同期しているブックでは、ThisWorkbook.Pathがhttpsで始まるURLになります。
本記事の関数でローカルのパスに変換し、フォルダが本当にあるかを確かめてから処理に使いましょう。

本記事が、Excel実務の効率化において、ご参考お役立てになれば幸いです。

Excelエラー解決サービス

環境が変わって動かなくなったマクロ、1件からご相談ください

  • 1件30,000円(税別)、対応時間は3時間以内です
  • 解決できなかった場合は料金をいただきません
  • リモート接続で、実際のPC環境を確認しながら対応します

セルネッツのExcelエラー解決サービスは、1件30,000円(税別)でご利用いただけます。解決できなかった場合は料金不要です。マクロの修正より運用の見直しが合う場合は、その旨も正直にお伝えします。相見積もりも歓迎しています。

\Excel専門特化 × 低価格 × スピード対応/

Excelエラー解決のご相談はこちら

全国対応・お見積もり無料


関連記事

Excelシステム開発

Excelを複数人で共同編集する方法|オンライン共有の手順と事例

更新日:2026年11月4日

Excelシステム開発

システム開発の依頼ガイド|費用相場・流れ・会社の選び方と「作りすぎない」判断軸

更新日:2026年9月24日

Excelシステム開発

予約システムの開発依頼にかかる費用相場|小規模店舗は100万円以下で作れる

更新日:2026年9月24日

Excelシステム開発

CRMシステム開発の外注費用は?依頼先の選び方と100万円以下に抑える考え方

更新日:2026年9月24日

Excelシステム開発

勤怠管理システム開発の外注費用相場|100万円以下で作る方法とプラン別料金【2026年版】

更新日:2026年9月24日

Excelシステム開発

SFAシステム開発の依頼相場は?高額SaaSに払い続ける前に知るべき「安く作る」現実解

更新日:2026年9月24日

Excelシステム開発

業務システム開発の依頼はいくら?費用相場と「100万円以下」で頼む方法

更新日:2026年9月24日

Excelシステム開発

受発注システム開発の費用相場は?外注料金の内訳と安く抑える方法を解説

更新日:2026年9月24日

Excelシステム開発

販売管理はエクセルで十分?売上管理表・発注管理表の作り方と「限界」の乗り越え方

更新日:2026年11月4日

newsite